1. Главная
  2. Хаб
  3. Сценарии
  4. Доступ как код: группы безопасности, SSH-ключи и доступ к машинам в Terraform

Сценарий 16

Доступ как код: группы безопасности, SSH-ключи и доступ к машинам в Terraform

Правила файрвола и список тех, кто может войти на машину по SSH, описываем в Terraform и храним в git. Любое изменение доступа проходит через merge request и terraform plan, поэтому его видно в истории репозитория. Те же операции — командами h3 для скриптов.

30 минСредний5 шагов Terraform, Безопасность, Серверы обновлено

Содержание
  1. 01Закрепите провайдер 0.3 и узнайте ID пользователей
  2. 02Опишите группу безопасности и её правила
  3. 03Опишите свой ключ и машину с этой группой
  4. 04Выдайте доступ коллеге кодом
  5. 05Меняйте доступ через merge request
  6. Проверка результата
  7. Как удалить ресурсы
  8. Типичные ошибки

Что получится

Репозиторий, в котором описаны группа безопасности с правилами, ваш SSH-ключ, машина с этой группой и SSH-доступ коллеги «только выбранными ключами». terraform plan показывает каждое изменение доступа до того, как оно применится, а отзыв доступа — это удаление блока в коде.

Что понадобится

  • Готовый проект Terraform с провайдером и state в S3 — из сценария «Инфраструктура как код».
  • Провайдер h3llo-cloud/h3 версии 0.3 и CLI h3 той же версии.
  • Коллега, которая уже участник проекта (не «Наблюдатель») и добавила свой SSH-ключ в профиль.
  1. Шаг 1. Закрепите провайдер 0.3 и узнайте ID пользователей

    SSH-ключи принадлежат пользователю, поэтому h3_ssh_key и h3_vm_ssh_access принимают ID пользователя. Список участников проекта с их ID и ключами возвращает API машин.

    Terraform

    versions.tf
    terraform {
      required_providers {
        h3 = {
          source  = "h3llo-cloud/h3"
          version = "~> 0.3.0"
        }
      }
    }
    
    # H3_KEY_ID, H3_SECRET_KEY и H3_PROJECT_ID — из окружения
    provider "h3" {}

    CLI

    Терминал
    h3 api GET /api/vms/v1/ssh-access/members -f projectId=$H3_PROJECT_ID \
      | jq '.items[] | {email, role, id: (.userId // .user_id), keys: [.keys[] | {name, type, id: (.keyId // .key_id)}]}'
    terraform.tfvars
    my_user_id       = "<ваш ID из списка выше>"
    alice_user_id    = "<ID коллеги>"
    alice_ssh_key_id = "<ID её ключа>"

    Проверка

    terraform init -upgrade скачал провайдер h3llo-cloud/h3 v0.3.x. В выводе h3 api вы видите себя и коллегу; у участника с ролью наблюдателя eligible: false — ему доступ не выдать.

  2. Шаг 2. Опишите группу безопасности и её правила

    Группа с блоками rule владеет всем набором правил: правило, добавленное вручную в консоли, следующий apply удалит. Это и есть смысл файрвола как кода. Если правила нужно добавлять из разных модулей, оставьте группу без rule и описывайте их ресурсами h3_security_group_rule — но не смешивайте оба способа на одной группе.

    Terraform

    firewall.tf
    variable "office_cidr" {
      type    = string
      default = "198.51.100.0/24"
    }
    
    resource "h3_security_group" "app" {
      name        = "app"
      description = "managed by terraform"
    
      rule {
        direction   = "ingress"
        protocol    = "tcp"
        port_from   = 22
        remote_cidr = var.office_cidr
        description = "SSH только из офиса"
      }
      rule {
        direction   = "ingress"
        protocol    = "tcp"
        port_from   = 443
        remote_cidr = "0.0.0.0/0"
        description = "HTTPS"
      }
      rule {
        direction   = "egress"
        remote_cidr = "0.0.0.0/0"
      }
    }

    CLI

    Терминал
    SG=$(h3 sg create --name app --description "managed by script" -o json | jq -r '.id')
    h3 sg rule add "$SG" --direction ingress --protocol tcp --port-from 22 --port-to 22 \
      --remote-cidr 198.51.100.0/24 --description "SSH только из офиса"
    h3 sg rule add "$SG" --direction ingress --protocol tcp --port-from 443 --port-to 443 \
      --remote-cidr 0.0.0.0/0 --description "HTTPS"
    h3 sg get "$SG"

    Проверка

    terraform plan показывает h3_security_group.app will be created с тремя правилами. После apply в консоли, раздел Группы безопасности, группа app в статусе «Применена».

    Если не получилось

    • Правило «22 с 0.0.0.0/0» консоль помечает предупреждением «Порт откроется всему интернету» — в коде такого предупреждения нет, поэтому смотрите на remote_cidr в ревью.
  3. Шаг 3. Опишите свой ключ и машину с этой группой

    ssh_key_ids — это ваш собственный доступ к машине в режиме «выбранные ключи». В 0.3 он меняется на месте, без пересоздания машины и без перезагрузки, когда включено управление ключами через агента (ssh_access_managed, по умолчанию у образов с qemu-guest-agent).

    Terraform

    vm.tf
    variable "my_user_id" { type = string }
    
    resource "h3_ssh_key" "me" {
      user_id    = var.my_user_id # владелец API-ключа
      name       = "me-laptop"
      public_key = file("~/.ssh/id_ed25519.pub")
    }
    
    resource "h3_vm" "app" {
      name        = "app-1"
      cpu         = 2
      memory      = "4Gi"
      image       = "ubuntu:24.04"
      disk_size   = "25Gi"
      white_ip    = true
      ssh_key_ids = [h3_ssh_key.me.id]
    
      lifecycle {
        prevent_destroy = true
      }
    }
    
    # группы машины целиком: перечисленные заменяют всё, что было
    resource "h3_vm_security_groups" "app" {
      vm_id              = h3_vm.app.id
      security_group_ids = [h3_security_group.app.id]
    }

    CLI

    Терминал
    h3 config set user_id <ваш ID>
    KEY=$(h3 ssh create --name me-laptop --key-file ~/.ssh/id_ed25519.pub -o json | jq -r '.id')
    h3 vm create --name app-1 --image ubuntu:24.04 --cpu 2 --memory 4Gi --ssh-key-ids "$KEY" --white-ip
    h3 sg vm set <vm-id> --groups "$SG"

    Проверка

    После apply вход работает: ssh user@$(terraform output -raw app_ip) (добавьте output "app_ip" { value = h3_vm.app.endpoint }). В карточке машины в секции «Группы безопасности» — только app.

    Если не получилось

    • Без h3_vm_security_groups машина остаётся в группе default, которая пропускает весь трафик.
    • Ключи, вписанные в /home/user/.ssh/authorized_keys руками, агент удаляет. Свои ключи вне платформы держите в ~/.ssh/authorized_keys2.
  4. Шаг 4. Выдайте доступ коллеге кодом

    mode = "selected" пускает только перечисленные ключи коллеги; mode = "all" — все её текущие и будущие ключи из профиля. Для прода берите selected: новый ключ на ноутбуке коллеги не должен сам попадать на боевые машины.

    Terraform

    access.tf
    variable "alice_user_id"    { type = string }
    variable "alice_ssh_key_id" { type = string }
    
    resource "h3_vm_ssh_access" "alice" {
      vm_id   = h3_vm.app.id
      user_id = var.alice_user_id
      mode    = "selected"
      key_ids = [var.alice_ssh_key_id]
    }

    CLI

    Терминал
    h3 vm ssh-access grant <vm-id> <ID коллеги> --mode selected --key-ids <ID её ключа>
    h3 vm ssh-access get <vm-id>

    Проверка

    terraform plan показывает одну запись h3_vm_ssh_access.alice will be created. После apply в карточке машины коллега в списке «Участники с доступом», статус «Применено» примерно через 2 минуты, а в «Журнал доступа» — «выдал доступ».

    Если не получилось

    • SSH_GRANTEE_VIEWER — у коллеги роль «Наблюдатель», ей SSH не выдаётся. SSH_KEY_NOT_OWNED — ID ключа принадлежит другому человеку.
  5. Шаг 5. Меняйте доступ через merge request

    Теперь доступ — обычный код. Отозвать доступ — удалить блок h3_vm_ssh_access; открыть порт — добавить rule. Ревьюер видит изменение в diff, а terraform plan в MR показывает, что именно поменяется.

    Отзыв доступа коллеги
    # удалите resource "h3_vm_ssh_access" "alice" из access.tf
    terraform plan    # h3_vm_ssh_access.alice will be destroyed
    terraform apply

    Права, выданные мимо Terraform (в консоли), plan покажет как расхождение для правил группы с блоками rule. Гранты других участников, которых нет в коде, Terraform не трогает — их видно в h3 vm ssh-access get.

    Проверка

    Коллеги больше нет в списке «Участники с доступом», в «Журнал доступа» — «отозвал доступ». Её ключ удалён из машины примерно за 2 минуты; уже открытые SSH-сессии не закрываются.

Проверка результата

Код и облако совпадают: plan пустой. Проверьте снаружи, что SSH пускает только из office_cidr, а HTTPS открыт всем.

Терминал
terraform plan -detailed-exitcode; echo "exit=$?"   # 0 — изменений нет
h3 sg get "$(terraform console <<< 'h3_security_group.app.id' | tr -d '"')"
h3 vm ssh-access get "$(terraform console <<< 'h3_vm.app.id' | tr -d '"')"

Как удалить ресурсы

terraform destroy удаляет всё, что описано. У машины стоит prevent_destroy — сначала уберите этот блок.

  1. Удалите lifecycle { prevent_destroy = true } из vm.tf.
  2. terraform destroy — удалит доступ коллеги, привязку групп, машину, группу app и ключ me-laptop. Публичный IP машины останется в проекте свободным и платным — удалите его в IP адреса или задайте release_eip_on_destroy = true до destroy.

Типичные ошибки

Где взять свой ID пользователя?

В выводе `h3 api GET /api/vms/v1/ssh-access/members -f projectId=…` найдите строку со своим email. Его же ждёт `h3 config set user_id` для команд `h3 ssh`.

Можно ли импортировать уже выданный в консоли доступ?

Да: `terraform import h3_vm_ssh_access.alice <vm_id>/<user_id>`, группу — `terraform import h3_security_group.app <id>`, правило — `terraform import h3_security_group_rule.x <sg_id>/<rule_id>`.

Меняю `ssh_key_ids` — машина пересоздастся?

В 0.3 нет: ключи меняются на месте и без перезагрузки. Машину пересоздаёт смена `image`, `disk_size` и `subnet_name` — `plan` пишет это как `must be replaced`.

Работает ли это в OpenTofu?

Да, провайдер тот же — `h3llo-cloud/h3`.

Связанные продукты и материалы

Попробовать в h3llo.cloud

Новым пользователям — 4 000 ₽ на 30 дней на любые сервисы: бонуса хватит, чтобы попробовать этот сценарий целиком. Бонус начисляется после подтверждения телефона и привязки карты.