1. Главная
  2. Хаб
  3. Сценарии
  4. Инфраструктура как код: сервер в Terraform и state в S3

Сценарий 05

Инфраструктура как код: сервер в Terraform и state в S3

Описываем сервер, группу безопасности и публичный IP в Terraform-провайдере h3llo-cloud/h3, храним state в объектном хранилище и меняем ресурсы через plan и apply. Работает и с OpenTofu.

35 минСредний6 шагов Terraform, Серверы, Сети, S3 обновлено

Содержание
  1. 01Создайте API-ключ и узнайте ID проекта
  2. 02Создайте бакет для state
  3. 03Опишите провайдер и backend
  4. 04Опишите сервер, группу безопасности и IP
  5. 05Посмотрите план и примените
  6. 06Измените ресурс через код
  7. Проверка результата
  8. Как удалить ресурсы
  9. Типичные ошибки
  10. Сколько стоит

Что получится

Репозиторий из трёх файлов .tf, по которому terraform apply поднимает сервер Ubuntu с публичным IP и группой безопасности 22/80/443. State хранится в бакете S3, а не на ноутбуке.

Что понадобится

  • Аккаунт h3llo.cloud и проект.
  • Terraform 1.6 или новее (или OpenTofu 1.6+).
  • SSH-ключ на вашем компьютере (~/.ssh/id_ed25519.pub; как создать — в шаге 1 сценария «Сайт на облачном сервере»).
  1. Шаг 1. Создайте API-ключ и узнайте ID проекта

    Провайдер подписывает каждый запрос ключом (HMAC). Ключ привязан к проектам, которые вы выберете при создании.

    Консоль

    1. Внизу левой панели нажмите значок ключа «API и SSH ключи» и откройте вкладку API-ключи.
    2. Нажмите Добавить ключ → Добавить API-ключ. В окне «Новый API ключ»: Имя ключа terraform, Проекты — ваш проект, Срок действия — «90 дней».
    3. Нажмите Создать API ключ. В окне «Ключ создан» скопируйте секретный ключ (начинается с h3_): «Он больше не будет отображаться».
    4. ID ключа — в списке ключей, строка «ID:» с кнопкой копирования. ID проекта — на странице «Обзор проекта» под названием (он же в адресе /console/project/<id>/).
    На вашем компьютере
    export H3_KEY_ID="<ID ключа>"
    export H3_SECRET_KEY="<секретный ключ h3_...>"
    export TF_VAR_project_id="<ID проекта>"
    export TF_VAR_ssh_public_key="$(cat ~/.ssh/id_ed25519.pub)"

    Если не получилось

    • Секретный ключ показывается один раз. Потеряли — создайте новый ключ, а старый удалите.
    • Не кладите ключи в .tf и в git: провайдер сам читает H3_KEY_ID и H3_SECRET_KEY из окружения.
  2. Шаг 2. Создайте бакет для state

    State хранит соответствие кода и реальных ресурсов. В бакете он не потеряется вместе с ноутбуком и доступен всей команде. Бакет создаём в консоли: Terraform нужен готовый бакет ещё до первого init.

    Консоль

    1. S3 хранилище → Создать бакет → Имя бакета tfstate-demo → Создать бакет.
    2. На странице «Бакеты S3» скопируйте «Публичный ключ» и «Приватный ключ» — это ключи S3, они отличаются от API-ключа.
    На вашем компьютере
    # backend "s3" читает стандартные переменные AWS
    export AWS_ACCESS_KEY_ID="<публичный ключ S3>"
    export AWS_SECRET_ACCESS_KEY="<приватный ключ S3>"
  3. Шаг 3. Опишите провайдер и backend

    Версию провайдера закрепляем как ~> 0.2.0: так обновления придут только в пределах 0.2.x, и код из сценария не сломается при выходе новой линейки. Хранилище S3 работает только с path-style-адресами, регион — default.

    Terraform

    versions.tf
    terraform {
      required_version = ">= 1.6"
    
      required_providers {
        h3 = {
          source  = "h3llo-cloud/h3"
          version = "~> 0.2.0"
        }
      }
    
      backend "s3" {
        bucket    = "tfstate-demo"
        key       = "web/terraform.tfstate"
        region    = "default"
        endpoints = { s3 = "https://storage.h3llo.cloud" }
    
        use_path_style              = true
        skip_credentials_validation = true
        skip_region_validation      = true
        skip_requesting_account_id  = true
        skip_metadata_api_check     = true
        skip_s3_checksum            = true
      }
    }
    
    # ключ — из H3_KEY_ID и H3_SECRET_KEY, адрес API по умолчанию https://api.h3llo.cloud
    provider "h3" {}
    Инициализация
    terraform init

    Проверка

    terraform init скачал провайдер h3llo-cloud/h3 v0.2.x и вывел Successfully configured the backend "s3"!.

    Если не получилось

    • Ошибка про аргументы endpoints или use_path_style в блоке backend — Terraform старше 1.6. Обновите его или используйте OpenTofu.
    • NoSuchBucket — имя в bucket не совпадает с созданным в консоли.
    • Блокировка state здесь не настроена: не запускайте apply одновременно из двух мест.
  4. Шаг 4. Опишите сервер, группу безопасности и IP

    Группа безопасности с блоками rule владеет всем набором правил, поэтому исходящий трафик прописан явно. Без привязки h3_vm_security_groups сервер остался бы в группе default, которая пропускает всё.

    Terraform

    main.tf
    variable "project_id" {
      type = string
    }
    
    variable "ssh_public_key" {
      type = string
    }
    
    resource "h3_security_group" "web" {
      project_id  = var.project_id
      name        = "web"
      description = "SSH, HTTP, HTTPS"
    
      rule {
        direction   = "ingress"
        protocol    = "tcp"
        port_from   = 22
        remote_cidr = "0.0.0.0/0"
      }
      rule {
        direction   = "ingress"
        protocol    = "tcp"
        port_from   = 80
        remote_cidr = "0.0.0.0/0"
      }
      rule {
        direction   = "ingress"
        protocol    = "tcp"
        port_from   = 443
        remote_cidr = "0.0.0.0/0"
      }
      rule {
        direction   = "egress"
        remote_cidr = "0.0.0.0/0"
      }
    }
    
    resource "h3_ovn_eip" "web" {
      project_id = var.project_id
      name       = "web-ip"
    }
    
    resource "h3_vm" "web" {
      project_id = var.project_id
      name       = "web-1"
      cpu        = 2
      memory     = "4Gi"
      image      = "ubuntu:24.04"
      disk_size  = "20Gi"
      ssh_key    = trimspace(var.ssh_public_key)
      white_ip   = true
      eip_id     = h3_ovn_eip.web.id
    }
    
    resource "h3_vm_security_groups" "web" {
      vm_id              = h3_vm.web.id
      security_group_ids = [h3_security_group.web.id]
    }
    
    output "public_ip" {
      value = h3_ovn_eip.web.ip_address
    }
    
    output "ssh_command" {
      value = "ssh user@${h3_ovn_eip.web.ip_address}"
    }

    Проверка

    Конфиг собран без ошибок:

    Терминал
    terraform fmt
    terraform validate

    Если не получилось

    • name: строчные латинские буквы, цифры и -, до 63 символов. Имя default для группы безопасности зарезервировано.
    • memory — в формате Kubernetes: "4Gi", "2048Mi". Памяти — не меньше, чем vCPU в ГБ, и не больше 16 ГБ на vCPU.
  5. Шаг 5. Посмотрите план и примените

    На вашем компьютере
    terraform plan -out web.plan
    terraform apply web.plan
    terraform output ssh_command

    Проверка

    План создаёт четыре ресурса — Plan: 4 to add, 0 to change, 0 to destroy. После apply сервер web-1 виден в консоли в разделе «Инстансы» со статусом «Работает», а в бакете tfstate-demo появился объект web/terraform.tfstate. Подключитесь:

    Терминал
    ssh user@$(terraform output -raw public_ip)

    Если не получилось

    • 401 / UNAUTHENTICATED — неверная пара ключа или часы компьютера расходятся с серверным временем больше чем на 5 минут: включите синхронизацию времени (NTP).
    • 403 / SCOPE_DENIED — проект не выбран в поле «Проекты» при создании ключа: создайте ключ заново с нужным проектом.
    • Missing API Key ID — в этом терминале не выполнены export из шага 1.
  6. Шаг 6. Измените ресурс через код

    Добавим серверу процессоров и памяти. cpu и memory меняются на месте — сервер перезагрузится, но не пересоздастся. А вот смена image, disk_size, ssh_key или white_ip пересоздаёт сервер вместе с диском: всегда читайте план перед apply.

    Terraform

    main.tf (фрагмент)
    resource "h3_vm" "web" {
      # ...
      cpu    = 4
      memory = "8Gi"
    }
    На вашем компьютере
    terraform plan
    terraform apply

    Проверка

    План показывает 0 to add, 1 to change, 0 to destroy и строку ~ update in-place у h3_vm.web. В карточке сервера в консоли — 4 vCPU и 8 ГБ.

    Если не получилось

    • В плане появилось must be replaced — вы меняете поле, которое пересоздаёт сервер. Отмените apply и проверьте изменения.

Проверка результата

Код и облако совпадают: повторный план пуст, а state лежит в бакете.

Терминал
terraform plan -detailed-exitcode; echo "exit=$?"   # 0 — изменений нет
terraform state list

Как удалить ресурсы

terraform destroy удаляет всё, что описано в коде: сервер с диском, привязку группы, группу безопасности и публичный IP.

Терминал

Терминал
terraform destroy
  1. Проверьте разделы Инстансы и IP адреса в консоли — там не должно остаться web-1 и web-ip.
  2. Удалите бакет state: S3 хранилище → tfstate-demo → меню «…» → Удалить → Удалить.
  3. Если ключ больше не нужен, удалите его на вкладке API-ключи.

Типичные ошибки

Провайдер отвечает 401, хотя ключ скопирован верно

Чаще всего расходятся часы: подпись запроса действительна 5 минут. Проверьте синхронизацию времени. Второй вариант — истёк «Срок действия» ключа: он виден в списке ключей.

Можно ли импортировать сервер, созданный в консоли?

Да: `terraform import h3_vm.web <id сервера>`. Группа безопасности импортируется по своему ID, привязка групп — по ID сервера (`h3_vm_security_groups`).

Где документация по всем ресурсам провайдера?

В реестре Terraform и на docs.h3llo.cloud/terraform.

Публичный IP остался после удаления сервера

Если адрес описан ресурсом `h3_ovn_eip`, его удалит `terraform destroy`. Если вместо него использовать только `white_ip = true`, адрес по умолчанию остаётся в проекте — задайте `release_eip_on_destroy = true`.

Связанные продукты и материалы

Сколько стоит

≈ 5,03 ₽ в час · 3 620,15 ₽ в месяц при работе 24/7

vCPU сервера2 × 900 ₽
RAM сервера, ГБ4 × 360 ₽
Диск до 20 000 IOPS*, ГБ20 × 14,40 ₽
Публичный IPv41 × 90 ₽
State в S3, ГБ (с запасом)1 × 2,15 ₽

Провайдер, API и группы безопасности бесплатны. terraform destroy в конце удалит всё, что создал.

Цены из прайс-листа, по которому работает биллинг; списание поминутное, месяц — 720 часов. Если удалить ресурсы после проверки, сценарий обойдётся в рубли.

Новым пользователям — 4 000 ₽ на 30 дней на любые сервисы: бонуса хватит, чтобы попробовать этот сценарий целиком. Бонус начисляется после подтверждения телефона и привязки карты.

* IOPS растут с объёмом диска; точные значения для вашего объёма видны в консоли при выборе.